Replace StirlingPDF with BentoPDF

hosts/bastion/profiles/caddy/default.nix

@@ -209,14 +209,8 @@
 
       "pdf.e10.camp" = {
         host = hosts.matrix;
-        port =
-          hosts.matrix.config.services.stirling-pdf.environment.SERVER_PORT;
+        inherit (hosts.matrix.config.services.bentopdf) port;
         protected = true;
-        extraConfig = ''
-          request_body {
-            max_size 2GiB
-          }
-        '';
       };
 
       "mazanoke.e10.camp" = {

hosts/matrix/configuration.nix

@@ -10,14 +10,14 @@
       profiles.networking.printing
       profiles.power.tripp-lite-smart1500lcd
       profiles.services.attic-watch-store.default
+      profiles.services.bentopdf
       profiles.services.changedetection-io
       profiles.services.e10-land
       profiles.services.glance.default
       profiles.services.mazanoke
       profiles.services.miniflux.default
       profiles.services.netbox.default
       profiles.services.paperless.default
-      profiles.services.stirling-pdf
       profiles.telemetry.prometheus-nut-exporter
       profiles.virtualisation.docker
       profiles.web-servers.caddy

modules/nixos/services/bentopdf/default.nix

@@ -0,0 +1,64 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let cfg = config.services.bentopdf;
+in {
+  options.services.bentopdf = {
+    enable = mkEnableOption "Enable bentopdf";
+
+    package = mkPackageOption pkgs "bentopdf" {
+      extraDescription = ''
+        To use the "simple mode" variant of bentopdf, which removes all socials, marketing and explanatory texts,
+        set this option to `pkgs.bentopdf.overrideAttrs { SIMPLE_MODE = true; }`
+      '';
+    };
+
+    host = mkOption {
+      type = types.str;
+      default = "0.0.0.0";
+      description = "The host to listen on.";
+    };
+
+    port = mkOption {
+      type = types.port;
+      default = 4152;
+      description = "The port nginx is listening on for bentopdf.";
+    };
+
+    openFirewall = mkOption {
+      type = types.bool;
+      default = false;
+      description = "Open the port nginx is listening on for bentopdf.";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    services.nginx = {
+      enable = true;
+
+      virtualHosts."bentopdf" = {
+        listen = [{
+          addr = cfg.host;
+          inherit (cfg) port;
+        }];
+
+        root = cfg.package;
+
+        locations."/".extraConfig = ''
+          try_files $uri $uri/ /index.html;
+          add_header X-Frame-Options "SAMEORIGIN" always;
+          add_header X-Content-Type-Options "nosniff" always;
+        '';
+
+        locations."~* .(js|css|png|jpg|jpeg|gif|ico|svg|woff|woff2|ttf|eot)$".extraConfig =
+          ''
+            expires 1y;
+            add_header Cache-Control "public, immutable";
+          '';
+      };
+    };
+
+    networking.firewall.allowedTCPPorts = optional cfg.openFirewall cfg.port;
+  };
+}

modules/overlays/default.nix

@@ -20,7 +20,8 @@
       # This is to pick up bugfix here: https://github.com/thanos-io/thanos/issues/7923
       inherit (nixpkgs-master) thanos;
 
-      inherit (self'.packages) fileflows mongodb-ce-6_0; # caddy-with-plugins;
+      inherit (self'.packages)
+        bentopdf fileflows mongodb-ce-6_0; # caddy-with-plugins;
     };
   };
 }

modules/packages/bentopdf/default.nix

@@ -0,0 +1,35 @@
+{ lib, buildNpmPackage, fetchFromGitHub, }:
+
+buildNpmPackage (finalAttrs: {
+  version = "1.11.2";
+  pname = "bentopdf";
+
+  src = fetchFromGitHub {
+    owner = "alam00000";
+    repo = "bentopdf";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-br4My0Q4zoA+ZIrXM4o4oQjZ7IpSdwg+iKiAUdc2B/s=";
+  };
+  npmDepsHash = "sha256-UNNNYO7e7qdumI0/ka2ieFZzKURPl1V3981vHCPcVfY=";
+
+  npmBuildScript = "build";
+  npmBuildFlags = [ "--" "--mode" "production" ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out
+    cp -r dist/* $out/
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Privacy-first PDF toolkit";
+    mainProgram = "bentopdf";
+    homepage = "https://bentopdf.com";
+    changelog = "https://github.com/alam00000/bentopdf/releases";
+    license = lib.licenses.asl20;
+    maintainers = [ ];
+  };
+})

modules/packages/default.nix

@@ -1,8 +1,9 @@
 _: {
   perSystem = { pkgs, ... }: {
     packages = {
-      mongodb-ce-6_0 = pkgs.callPackage ./mongodb-ce-6_0 { };
+      bentopdf = pkgs.callPackage ./bentopdf { };
       fileflows = pkgs.callPackage ./fileflows { };
+      mongodb-ce-6_0 = pkgs.callPackage ./mongodb-ce-6_0 { };
     };
   };
 }

modules/profiles/observability/gatus/default.nix

@@ -269,7 +269,7 @@ in { config, lib, ... }: {
             group = "Matrix";
           })
           (mkEndpoint {
-            name = "Stirling PDF";
+            name = "BentoPDF";
             url = "https://pdf.e10.camp";
             group = "Matrix";
             protected = true;

modules/profiles/services/bentopdf.nix

@@ -0,0 +1,7 @@
+{ pkgs, ... }: {
+  services.bentopdf = {
+    enable = true;
+    package = pkgs.bentopdf.overrideAttrs { SIMPLE_MODE = true; };
+    openFirewall = true;
+  };
+}

modules/profiles/services/glance/default.nix

@@ -126,9 +126,9 @@
                     icon = "di:blocky";
                   }
                   {
-                    title = "Stirling PDF";
+                    title = "BentoPDF";
                     url = "https://pdf.e10.camp";
-                    icon = "di:stirling-pdf";
+                    icon = "di:bentopdf";
                     alt-status-codes = [ 401 ];
                   }
                   {